/*
**	Monte Carlo Program for Weak Ideal conditions III
*/


@ Data generation under Weak Ideal Conditions @

/*
** The regressors are lagged dependent variables.
** That is, regressors are stochastic.
** The errors are different across different data sets
** Errors are normal:
*/

@  Model: y(t) = beta(1) + beta(2)*y(t-1) + e @


seed   = 1 ;
beta2  = 0.5 ;
beta1 = 0.1;
tt       = 200; @ # of observations @
kk      = 2;  @ # of betas @
iter    = 5000; @ # of sets of different data @

storb  = zeros(iter,1);
storse = zeros(iter,1);
stort  = zeros(iter,1);

i = 1; do while i <= iter;

@ Generating y  @

y = 0 ;
j = 1; do while j <= tt;
y = y|(beta1+beta2*y[j,.]+2*rndns(1,1,seed) );
j = j + 1; endo;


@	OLS using yy and xx  @

yy = y[2:tt+1,.];
xx = ones(tt,1)~y[1:tt,.];

b  = invpd(xx'xx)*(xx'yy);
e  = yy - xx*b ;

s2 = (e'e)/(tt-kk);
v  = s2*invpd(xx'xx);

se = sqrt(diag(v));

storb[i,1]  = b[2,1];
storse[i,1] = se[2,1];
stort[i,1] = (b[2,1]-beta2)/se[2,1];

i = i + 1; endo;

@ Reporting Monte Carlo results @

output file = wicmonte3.out reset;

format /rd 12,3;

"Monte Carlo results";
"-----------";
"Mean of OLS b(2)                ="  meanc(storb);
"s.e. of OLS b(2)                   ="  stdc(storb);
"mean of estimated s.e. of OLS b(2) =" meanc(storse) ;

library pgraph;
graphset;
{a1,a2,a3}=hist(storb,50);
output off ;