CREATE; IND = TRN(5,0) ; PER = TRN(-5,0) $
 
? SPECIFIY # OF OBS.
CALC  ; NN = 500 ; TT = 5  $
 
? SPECIFY # OF TIME-VARYING VARIABLES (KK)
? SPECIFYING # OF TIME-INVARIANT VARIABLES

CALC  ; KK = 4 ; GG = 4 $
 
? PROGRAMS FOR WITHIN ESTIMATION
 
CREATE ; WX1 = X1 - X1B
       ; WX2 = X2 - X2B
       ; WX3 = X3 - X3B
       ; WX4 = X4 - X4B
       ; WY  = Y  - YB            $
NAMELIST ; WX = WX1,WX2,WX3,WX4   $
TYPE     ; WITHIN ESTIMATION RESULTS    $
REGRESS  ; LHS = WY ; RHS = WX          $
CALC    ; LIST ; SIGMAE2 = SUMSQDEV/(NN*(TT-1)-KK)  $
 
MATRIX  ; WB = B
        ; WCOV = SIGMAE2*XPXI(WX)
        ; STAT(WB,WCOV)                     $
 
? PROGRAM FOR GLS MODEL
 
TYPE   ; BETWEEN ESTIMATION RESULTS $
REGRESS; LHS = YB ; RHS = X1B,X2B,X3B,X4B,ONE,Z2,Z3,Z4 $
CALC   ; LIST
       ; SIGMAA2 = SUMSQDEV/(NN-KK-GG)
       ; THET = SQR(SIGMAE2/SIGMAA2)
       ; THE = 1-THET  $
SAMPLE ; ALL $
CREATE ; THEY = Y - THE*YB
       ; THEONE = THET
       ; THEX1 = X1 - THE*X1B
       ; THEX2 = X2 - THE*X2B
       ; THEX3 = X3 - THE*X3B
       ; THEX4 = X4 - THE*X4B
       ; THEZ2 = THET*Z2
       ; THEZ3 = THET*Z3
       ; THEZ4 = THET*Z4   $
 
NAMELIST ; THEX = THEX1,THEX2,THEX3,THEX4,THEONE,THEZ2,THEZ3,THEZ4 $
 
REGRESS; LHS = THEY
       ; RHS = THEX
       ; RES = RESY  $
TYPE   ; GLS RESULTS $
MATRIX ; REB = B
       ; RECOV = SIGMAE2*XPXI(THEX)
       ; STAT(REB,RECOV)       $
 
? HAUSMAN TEST RESULTS
TYPE   ; HAUSMAN TEST RESULTS  $
 
MATRIX ; REB13 = PART(REB,1,4) ; RECOV13 = PART(RECOV,1,4,1,4) $
MATRIX ; DIFB = WB~REB13 $
MATRIX ; INVCOV = WCOV~RECOV13  $
MATRIX ; DIFV  = SINV(INVCOV)
       ; HTEST = DIFB'|DIFV|DIFB $
CALC   ; LIST
       ; HT = HTEST
       ; P_VAL = 1 - CHI(HT,KK) $
 
? ALTERNATIVES OF HAUSMAN TEST
 
NAMELIST ; TESTX1 = WX1,WX2,WX3,WX4,ONE,Z2,Z3,Z4,X1B,X2B,X3B,X4B $
REGRESS  ; LHS = RESY ; RHS = TESTX1
         ; KEEP = FRESY             $
 
TYPE     ; ALT1 TEST  $
CALC     ; LIST
         ; ALT1 = TT*NN*RSQRD
         ; P_VAL = 1 - CHI(ALT1,KK) $
 
TYPE     ; ALT2 TEST $
CALC     ; LIST
         ; ALT2 = DOT(FRESY,FRESY)/SIGMAE2
         ; HT = HT
         ; P_VAL = 1 - CHI(ALT2,KK) $
 
NAMELIST ; TESTX2 = WX,ONE,Z2,Z3,Z4,
                    X11AM,X12AM,X13AM,X14AM,X15AM,
                    X21AM,X22AM,X23AM,X24AM,X25AM,
                    X31AM,X32AM,X33AM,X34AM,X35AM,
                    X41AM,X42AM,X43AM,X44AM,X45AM $

TYPE     ; ALT3 TEST $
CALC     ; DD = KK*TT ;
REGRESS  ; LHS = RESY ; RHS = TESTX2 $
CALC     ; LIST
         ; ALT3 = TT*NN*RSQRD
         ; P_VAL = 1 - CHI(ALT3,DD) $